Comment puis-je obtenir la date actuelle sur la ligne de commande Windows, dans un format approprié pour l'utilisation dans un nom de fichier?

Régional indépendant date du temps d'analyse

le format de sortie de %DATE% et de la commande dir est régionalement dépendant et donc ni robuste ni intelligent. date.exe (partie de UnxUtils ) fournit toute information sur la date et l'heure dans n'importe quel format pensable. Vous pouvez également extraire les informations de date/Heure de n'importe quel fichier avec date.exe .

Exemples: (dans un cmd-script utiliser %% au lieu de %)

date.exe +"%Y-%m-%d"

2009-12-22

date.exe +"%T"

18:55 :03

date.exe +"%Y%m%d %H%M%S: Any text"

20091222 185503: tout texte

date.exe +"Text: %y/%m/%d-any text-%H.%M"

Texte: 09/12/22-texte-ŕ 18.55

Command: date.exe +"%m-%d """%H %M %S """"

07-22 "18:55:03"`

information sur la date et l'heure provenant d'un fichier de référence:

date.exe -r c:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

L'utiliser dans un script CMD pour obtenir des informations sur l'année, le mois, le jour et l'heure:

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

L'utiliser dans un script CMD pour obtenir une horodatage dans n'importe quel format requis:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

extraire l'information date/Heure de n'importe quel fichier de référence.

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

ajouter à un fichier sa date/heure information:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe est partie des outils libres GNU qui n'ont pas besoin d'installation.

NOTE: copier date.exe dans n'importe quel répertoire qui se trouve dans le chemin de recherche peut entraîner la défaillance d'Autres scripts qui utilisent la commande date intégrée à Windows.

deux autres façons qui ne dépendent pas des paramètres de temps (Toutes les deux tirées de :comment obtenir des données/temps indépendant de la localisation: ). Et les deux ont aussi le jour de la semaine et aucun d'eux n'a besoin de permissions admin!:

1. MAKECAB - va fonctionner sur tous les systèmes de Windows (rapide, mais crée un petit fichier temp) (le script foxidrive):

   @echo off
   pushd "%temp%"
   makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
   for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
      set "current-date=%%e-%%b-%%c"
      set "current-time=%%d"
      set "weekday=%%a"
   )
   del ~.*
   popd
   echo %weekday% %current-date% %current-time%
   pause
   

   Pour en savoir plus sur la fonction get-date .

2. ROBOCOPY - ce n'est pas une commande native pour Windows XP et Windows Server 2003, mais il peut être téléchargé à partir du site de microsoft . Mais est intégré dans tout de Windows Vista et au-dessus:

   @echo off
   setlocal
   for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
    set "dow=%%D"
    set "month=%%E"
    set "day=%%F"
    set "HH=%%G"
    set "MM=%%H"
    set "SS=%%I"
    set "year=%%J"
   )
   
   echo Day of the week: %dow%
   echo Day of the month : %day%
   echo Month : %month%
   echo hour : %HH%
   echo minutes : %MM%
   echo seconds : %SS%
   echo year : %year%
   endlocal
   

   et trois autres façons qui utilisent D'autres langues de script Windows. Ils vous donneront plus de flexibilité par exemple vous pouvez obtenir de la semaine de l'année, le temps en millisecondes et ainsi de suite.

3. JScript/lot hybride (il faut être enregistré en tant que .bat ). JScript est disponible sur tous les formulaires de système NT et au-dessus, dans le cadre de Windows Script Host ( bien que peut être désactivé par le registre il est un cas rare ):

   @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment
   
   @echo off
   cscript //E:JScript //nologo "%~f0"
   exit /b 0
   *------------------------------------------------------------------------------*/
   
   function GetCurrentDate() {
           // Today date time which will used to set as default date.
           var todayDate = new Date();
           todayDate = todayDate.getFullYear() + "-" +
                          ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                          ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                          ("0" + todayDate.getMinutes()).slice(-2);
   
           return todayDate;
       }
   
   WScript.Echo(GetCurrentDate());
   

4. VSCRIPT/LOT hybride ( Est-il possible d'incorporer et d'exécuter VBScript dans un fichier de commandes sans l'aide d'un fichier temporaire? ) même cas que JScript, mais l'hybridation n'est pas si parfaite:

   :sub echo(str) :end sub
   echo off
   '>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
   '& echo current date:
   '& cscript /nologo /E:vbscript "%~f0"
   '& exit /b
   
   '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
   '1 = vbLongDate - Returns date: weekday, monthname, year
   '2 = vbShortDate - Returns date: mm/dd/yy
   '3 = vbLongTime - Returns time: hh:mm:ss PM/AM
   '4 = vbShortTime - Return time: hh:mm
   
   WScript.echo  Replace(FormatDateTime(Date,1),", ","-")
   

5. PowerShell - peut être installé sur chaque machine qui a .net-télécharger de Microsoft ( v1 , v2 , v3 (seulement pour Windows 7 et supérieur)). Il est installé par défaut sur tout depuis Windows 7 / Windows Server 2008 et au-dessus:

   C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
   

   pour l'utiliser à partir d'un fichier de lot:

   for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
   

6. auto-compilé jscript.net/batch (jamais vu une machine Windows sans .NET, donc je pense que c'est un assez portable):

   @if (@X)==(@Y) @end /****** silent line that start JScript comment ******
   
   @echo off
   ::::::::::::::::::::::::::::::::::::
   :::       Compile the script    ::::
   ::::::::::::::::::::::::::::::::::::
   setlocal
   if exist "%~n0.exe" goto :skip_compilation
   
   set "frm=%SystemRoot%\Microsoft.NET\Framework\"
   
   :: Searching the latest installed .NET framework
   for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
       if exist "%%v\jsc.exe" (
           rem :: the javascript.net compiler
           set "jsc=%%~dpsnfxv\jsc.exe"
           goto :break_loop
       )
   )
   echo jsc.exe not found && exit /b 0
   :break_loop
   
   
   call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
   ::::::::::::::::::::::::::::::::::::
   :::       End of compilation    ::::
   ::::::::::::::::::::::::::::::::::::
   :skip_compilation
   
   "%~n0.exe"
   
   exit /b 0
   
   
   ****** End of JScript comment ******/
   import System;
   import System.IO;
   
   var dt=DateTime.Now;
   Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));
   

7. Logman Cela ne peut pas obtenir de l'an et le jour de la semaine. Il est relativement lent et crée également un fichier temporaire et est basé sur les horodatage que logman met sur ses fichiers journaux. Il fonctionnera sur tout de Windows XP et au-dessus. Il ne sera probablement jamais utilisé par quiconque-y compris moi - mais c'est une façon de plus...

   @echo off
   setlocal
   del /q /f %temp%\timestampfile_*
   
   Logman.exe stop ts-CPU 1>nul 2>&1
   Logman.exe delete ts-CPU 1>nul 2>&1
   
   Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
   Logman.exe start ts-CPU 1>nul 2>&1
   
   Logman.exe stop ts-CPU >nul 2>&1
   Logman.exe delete ts-CPU >nul 2>&1
   for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t
   
   echo %timestamp%
   echo MM: %timestamp:~0,2%
   echo dd: %timestamp:~2,2%
   echo hh: %timestamp:~4,2%
   echo mm: %timestamp:~6,2%
   
   endlocal
   exit /b 0
   

8. Une façon de plus avec WMIC qui donne aussi la semaine de l'année et du jour de la semaine, mais pas des millisecondes (pour des millisecondes, voir la réponse de foxidrive):

   for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
   echo %day%
   echo %DayOfWeek%
   echo %hour%
   echo %minute%
   echo %month%
   echo %quarter%
   echo %second%
   echo %weekinmonth%
   echo %year%
   

9. utilisant TYPEPERF avec quelques efforts pour être rapide et compatible avec différents paramètres de langue et aussi rapide que possible:

   @echo off
   setlocal
   
   :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
   ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")
   
   for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
   set "mon="
   for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
      if not defined mon (
         for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
           set mon=%%a
           set date=%%b
           set year=%%c
           set hour=%%d
           set minute=%%e
           set sec=%%f
           set ms=%%g
         )
      )
   )
   echo %year%.%mon%.%date%
   echo %hour%:%minute%:%sec%.%ms%
   endlocal
   

10. MSHTA permet d'appeler des méthodes JavaScript similaires à la méthode JScript démontrée au n ° 3 ci-dessus. Gardez à l'esprit que les propriétés Date object de JavaScript impliquant des valeurs de mois sont numérotées de 0 à 11, Pas de 1 à 12. Donc une valeur de 9 signifie octobre.

    <!-- : Batch portion
    
    @echo off
    setlocal
    
    for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"
    
    rem Display all variables beginning with "now."
    set now.
    
    goto :EOF
    
    end batch / begin HTA -->
    
    <script>
        resizeTo(0,0)
        var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
            now = new Date(),
            props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
                'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
                'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
                'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
                'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
            output = [];
    
        for (var i in props) {output.push(props[i] + '()=' + now[props[i]]())}
        close(fso.Write(output.join('\n')));
    </script>
    

voici une variante de l'alt.ms-dos.lot.nt qui fonctionne localement-indépendamment.

mettez ceci dans un fichier texte, par exemple getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

pour obtenir le code de travailler sans Erreur msg à stderr, j'ai dû ajouter les guillemets simples arount les assignations variables pour %%%a, %%b et % % C. Ma locale (PT) causait des erreurs à un moment de la boucle/parsing où des choses comme "set =20" étaient exécutées. Les citations donnent un jeton (bien que vide) pour le côté gauche de l'instruction d'affectation.

l'inconvénient est le désordre des noms de variables locales: 'yy', 'mm' et 'dd'. Mais bon, qui s'en soucie!

j'utilise ceci (encore une fois pas de la région indépendant (royaume-UNI))

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%

malheureusement, cela n'est pas à l'abri des contextes régionaux, mais il fait ce que vous voulez.

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

Incroyable les choses que vous pouvez trouver sur Wikipedia .

s'il vous plaît utiliser le script suivant pour obtenir le jour en cours dans la ligne de commande:

echo %Date:~0,3%day

les quatre premières lignes de ce code vous donnera fiable YY JJ MM YYYY hh Min Sec variables dans Windows XP Professionnel et supérieur.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

une Autre façon ( crédit ):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

notez que mes deux réponses ici dépendent toujours de l'ordre du jour et du mois tel que déterminé par les contextes régionaux - pas sûr de savoir comment faire pour contourner cela.

"d:\Program Files-Zipz.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

ce n'est pas vraiment plus bref mais pourrait être une façon plus souple ( crédit ):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%

Voici une façon d'obtenir l'Heure de la date dans une seule ligne:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

Dans les NOUS ce sera la sortie de "aaaa-mm-jj hhmm". Différents paramètres régionaux donneront des résultats différents en %date%, mais vous pouvez modifier l'ordre des tokens.

si vous voulez un format différent, modifiez la déclaration echo en réarrangeant les tokens ou en utilisant des séparateurs différents (ou non).

courte réponse:

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result 

longue réponse

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE

et voici un fichier batch similaire pour la partie temporelle.

:: /q/how-do-i-get-current-datetime-on-the-windows-command-line-in-a-suitable-format-for-using-in-a-filename-53145/"tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen

j'ai changé la réponse avec le fichier de commandes à partir de vMax de sorte qu'il fonctionne avec la langue néerlandaise.

Les Hollandais - aussi persistants que nous - ont quelques changements dans les %date% , date/t , et date qui cassent le fichier de lot d'origine.

ce serait bien si certaines personnes pouvaient vérifier cela aussi bien par rapport à D'autres fenêtres locales, et rapporter les résultats.

Si le fichier batch échoue à votre emplacement, alors s'il Vous Plaît inclure la sortie de ces deux énoncés sur l'invite de commande:

echo:^|date

date/t

ceci est un échantillon de la sortie que vous devriez obtenir à partir du fichier par lots:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

voici le code révisé avec des commentaires sur le pourquoi:

:: /q/how-do-i-get-current-datetime-on-the-windows-command-line-in-a-suitable-format-for-using-in-a-filename-53145/"%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen

Matthew Johnson one-liner solution pour obtenir le one-liner date et de l'heure est éloquent et utile.

il faut cependant une simple modification pour fonctionner à partir d'un fichier par lots:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e

il suffit d'utiliser cette ligne:

PowerShell -Command "get-date"

une fonction qui est basée sur wmic :

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

à l'Envers: "151990920 de la" Région autonome. inconvénient: seuls les administrateurs système peuvent exécuter wmic.EXE.

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

2014-01-22 12:51:53