Est-il possible d'intégrer et d'exécuter VBScript dans un fichier batch sans utiliser un fichier temporaire?

Note-saut à la mise à jour 2014-04-27 section au bas de cette réponse pour la meilleure solution.

je pensais que la réponse était non. Mais L'utilisateur de DosTips Liviu a découvert que le caractère <SUB> (Ctrl-Z, 0x1A, décimal 26) a des effets de bizare lorsqu'il est intégré dans un fichier batch. Si fonctionne un peu comme un terminateur de ligne tel qu'il est possible pour les commandes par lots qui suivent un REM (ou un hack:: remark) à exécuter si elles sont précédées de Ctrl-Z. http://www.dostips.com/forum/viewtopic.php?p=13160#p13160

cela a été confirmé sur XP Home Edition sp3, Vista Home Premium sp2 64 bit, et Vista Enterprise sp2 32 bit. Je suppose que ça marche sur D'autres versions de Windows.

Note - le code ci-dessous est supposé avoir des caractères Ctrl-Z intégrés. Je vous jure j'ai l'habitude de voir sur ce site lors de l'affichage avec IE8. Mais ils semblent avoir été perdus de ce poste en quelque sorte et je ne peux pas comprendre comment les poster plus. J'ai remplacé les caractères par la chaîne <SUB>

::<sub>echo This will execute in batch, but it will fail as vbs.
rem<SUB>echo This will execute in batch, and it is also a valid vbs comment
::'<SUB>echo This will execute in batch and it is also a valid vbs comment

qui est la clé d'un succès de lot/VBS hybride. Aussi longtemps que chaque commande par lots est précédée de rem<SUB> ou ::'<SUB> , alors le moteur vbs Je ne le verrai pas, mais la commande batch s'exécutera. Assurez-vous simplement de terminer la partie de lot avec un EXIT ou EXIT /B . Puis le reste du script peut être normale vbs.

vous pouvez même avoir une étiquette de lot si nécessaire. :'Label est à la fois un commentaire vbs valide et une étiquette de lot valide.

voici un script hybride trivial. (de nouveau avec <SUB> à la place de CTRL-Z)

::'<SUB>@cscript //nologo //e:vbscript "%~f0" & exit /b
WScript.Echo "Example of a hybrid VBS / batch file"

mise à jour 2012-04-15

jeb a trouvé une solution qui évite le maladroit CTRL-Z, mais il imprime ECHO OFF Au début et définit également quelques variables externes.

j'ai trouvé une solution sans CTRL-Z qui élimine les variables externes et est plus simple à comprendre.

normalement les caractères spéciaux & , | , < , > etc. ne pas travailler après une déclaration REM en lot. Mais les caractères spéciaux fonctionnent après REM. . J'ai trouvé cette pépite d'information à http://www.dostips.com/forum/viewtopic.php?p=3500#p3500 . Un test montre que REM. est toujours un commentaire VBS valide. EDIT - sur la base du commentaire de jeb, il est plus sûr d'utiliser REM^ (il y a un espace après le caret.)

voici donc un hybride trivial VBS/batch utilisant REM^ & . Le seul inconvénient est qu'il imprime REM & au début, tandis que la solution de jeb imprime ECHO OFF .

rem^ &@cscript //nologo //e:vbscript "%~f0" & exit /b
WScript.Echo "Example of a hybrid VBS / batch file"

voici un autre exemple trivial qui démontre plusieurs commandes par lots, y compris un appel à une sous-routine étiquetée.

::' VBS/Batch Hybrid

::' --- Batch portion ---------
rem^ &@echo off
rem^ &call :'sub
rem^ &exit /b

:'sub
rem^ &echo begin batch
rem^ &cscript //nologo //e:vbscript "%~f0"
rem^ &echo end batch
rem^ &exit /b

'----- VBS portion ------------
wscript.echo "begin VBS"
wscript.echo "end VBS"
'wscript.quit(0)

j'aime toujours la solution CTRL-Z parce qu'elle élimine tous les sortie.

mise à jour 2012-12-17

Tom Lavedas a publié une méthode pour exécuter commodément VBS dynamique à partir d'un script par lots sur Google Groups: no file VBS hybrid scripting . La méthode utilise mshta.exe (Microsoft HTML Application Host).

sa solution de série originale reposait sur un petit VBS externe.BAT script pour exécuter le VBS dans un FOR / F. J'ai légèrement modifié la syntaxe pour qu'il soit pratique d'intégrer directement dans un script de traitement par lots donné.

c'est assez lent, mais très pratique. Il est limité à l'exécution d'une seule ligne de VBS.

le VBS est écrit normalement, sauf que toutes les citations doivent être doublées: une citation contenant une chaîne de caractères doit être écrite comme "" , et les citations internes à une chaîne de caractères doivent être écrites comme """" . Normalement, le mini script est exécuté dans le() clause de A FOR / F. Il peut être exécuté directement, mais seulement si stdout a été redirigé ou pipé.

il devrait fonctionner sur N'importe quel système D'exploitation Windows à partir de XP aussi longtemps que IE est installé.

@echo off
setlocal
:: Define simple batch "macros" to implement VBS within batch
set "vbsBegin=mshta vbscript:Execute("createobject(""scripting.filesystemobject"")"
set "vbsBegin=%vbsBegin%.GetStandardStream(1).write("
set ^"vbsEnd=):close"^)"

:: Get yesterday's date
for /f %%Y in ('%vbsBegin% date-1 %vbsEnd%') do set Yesterday=%%Y
set Yesterday
pause
echo(

:: Get pi
for /f %%P in ('%vbsBegin% 4*atn(1) %vbsEnd%') do set PI=%%P
set PI
pause
echo(

set "var=name=value"
echo Before - %var%
:: Replace =
for /f "delims=" %%S in (
  '%vbsBegin% replace(""%var%"",""="","": "") %vbsEnd%'
) do set "var=%%S"
echo After  - %var%
pause
echo(

echo Extended ASCII:
for /l %%N in (0,1,255) do (

  %=  Get extended ASCII char, except can't work for 0x00, 0x0A.  =%
  %=  Quotes are only needed for 0x0D                             =%
  %=    Enclosing string quote must be coded as ""                =%
  %=    Internal string quote must be coded as """"               =%
  for /f delims^=^ eol^= %%C in (
    '%vbsBegin% """"""""+chr(%%N)+"""""""" %vbsEnd%'
  ) do set "char.%%N=%%~C"

  %=  Display result  =%
  if defined char.%%N (
    setlocal enableDelayedExpansion
    echo(   %%N: [ !char.%%N! ]
    endlocal
  ) else echo(   %%N: Doesn't work :(
)
pause
echo(

:: Executing the mini VBS script directly like the commented code below 
:: will not work because mshta fails unless stdout has been redirected
:: or piped.
::
::    %vbsBegin% ""Hello world"" %vbsEnd%
::

:: But this works because output has been piped
%vbsBegin% ""Hello world"" %vbsEnd% | findstr "^"
pause

mise à jour 2014-04-27

Plus de à DosTips il y a un grand recueil de js/vbs/html/hta hybrides et chimères dans cmd/chauve-souris . Beaucoup de bonnes choses de diverses personnes.

dans ce fil, Liviu de DosTips Utilisateur a découvert une belle VBS/lot hybride solution qui utilise WSF.

<!-- : Begin batch script
@echo off
cscript //nologo "%~f0?.wsf"
exit /b

----- Begin wsf script --->
<job><script language="VBScript">
  WScript.Echo "VBScript output called by batch"
</script></job>

je pense que cette solution est fantastique. Les sections batch et WSF sont clairement séparées par de beaux en-têtes. Le code de lot est absolument normal, sans aucune syntaxe étrange. La seule restriction est que le code de lot ne peut pas contenir --> .

de même, la Le code VBS dans WSF est absolument normal. La seule restriction est que le code VBS ne peut pas contenir </script> .

le seul risque est l'utilisation non documentée de "%~f0?.wsf" comme script à charger. D'une façon ou d'une autre, l'analyseur trouve et charge correctement le fonctionnement .BAT script "%~f0" , et le suffixe ?.wsf donne mystérieusement instruction à CSCRIPT d'interpréter le script comme WSF. Avec un peu de chance, MicroSoft ne désactivera jamais cette "fonctionnalité".

depuis la solution utilise WSF, le script de fournée peut contenir n'importe quel nombre de VBS indépendants, JScript, ou d'autres travaux qui peuvent être sélectivement appelés. Chaque tâche peut même utiliser plusieurs langues.

<!-- : Begin batch script
@echo off
echo batch output
cscript //nologo "%~f0?.wsf" //job:JS
cscript //nologo "%~f0?.wsf" //job:VBS
exit /b

----- Begin wsf script --->
<package>
  <job id="JS">
    <script language="VBScript">
      sub vbsEcho()
        WScript.Echo "VBScript output called by JScript called by batch"
      end sub
    </script>
    <script language="JScript">
      WScript.Echo("JScript output called by batch");
      vbsEcho();
    </script>
  </job>
  <job id="VBS">
    <script language="JScript">
      function jsEcho() {
        WScript.Echo("JScript output called by VBScript called by batch");
      }
    </script>
    <script language="VBScript">
      WScript.Echo "VBScript output called by batch"
      call jsEcho
    </script>
  </job>
</package>