Techniques de programmation simples / astuces dans Mathematica pour faire des graphiques pour le livre de mathématiques? [fermé]

j'ai essayé de l'utiliser. Et c'est vraiment agréable pour certaines parcelles, mais quand il s'agit de faire par exemple un triangle Je l'ai trouvé assez compliqué. J'ai trouvé comment dessiner un triangle mais comment ajouter ces marques d'angle, ces lignes courbes?

et puisque je suis débutant dans ce travail, de l'écriture d'un livre, n'importe qui peut me recommander qui est la meilleure façon d'accomplir de beaux graphiques, par exemple comme dans l'image ci-dessous. Quels sont les programmes les plus appropriés. enter image description here

Merci pour toutes suggestions et recommandations.

35
demandé sur Martin Nycander 2012-01-05 23:09:28

6 réponses

Voici une façon simple / basique de faire la première: 

Graphics[{

 (* The dashed circle segment *)
 {
  Dashing[{.04, .01}], 
  Darker[Orange], 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {1, 2 \[Pi]}]
 },

 (* The solid circle segment *)
 {
  Orange, 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {0, 1}]
 },

 (* The radial lines and the small circle segment *)
 Line[{{0, 0}, {1, 0}}],
 Line[{{0, 0}, {Cos[1], Sin[1]}}],
 Circle[{0, 0}, .2, {0, 1}],

 (* Various text labels *)
 {
  Text[Style["\[Theta]", 24], .3 {Cos[.5], Sin[.5]}], 
  Text[Style["s", 24], 1.1 {Cos[.5], Sin[.5]}], 
  Text[Style["r", 24], {.5, -.1}]
 }
}]

Mathematica graphics

ce qui suit est exactement la même chose, mais enveloppé dans Manipulate et paramétrable sur l'angle alpha : 

Manipulate[
 Graphics[{
  {Dashing[{.04, .01}], Darker[Orange], AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {\[Alpha], 2 \[Pi]}]},
  {Orange, AbsoluteThickness[2], Circle[{0, 0}, 1, {0, \[Alpha]}]},
  Line[{{0, 0}, {1, 0}}],
  Line[{{0, 0}, {Cos[\[Alpha]], Sin[\[Alpha]]}}],
  Circle[{0, 0}, .2, {0, \[Alpha]}],
  {Text[Style["\[Theta]", 
  24], .3 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["s", 24], 1.1 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["r", 24], {.5, -.1}]}
 }],
{{\[Alpha], 1}, 0, 2 \[Pi]}]

si vous déplacez le curseur, le contenu changera en conséquence:

Mathematica graphics

19
répondu Arnoud Buzing 2012-01-05 22:36:38

Modifier Vous pouvez obtenir l'inspiration des Manifestations projet de trop. ce sont les démonstrations du triangle. après un rapide coup d'oeil, je pense que vous devriez voir les démonstrations liées à la géométrie par Jay Warendorff . Il a fait beaucoup de ceux-ci, et ils utilisent un ensemble structuré de fonctions liées à la géométrie que vous pouvez très probablement réutiliser.

Fonction angleArc pour commencer. C'est juste un petit exemple d'une fonction d'aide que vous pourriez utiliser, il y a beaucoup de place pour l'amélioration. 

angleArc[Polygon[vertices_List, ___], r_, i_] :=
 Module[{a, b, c, phi1, phi2},
  {a, b, c} = Take[RotateLeft[vertices, i-2], 3];
  {phi1, phi2} = Sort@N[{ArcTan @@ (a - b), ArcTan @@ (c - b)}];
  If[phi2 - phi1 > Pi, phi1 += 2 Pi];
  Circle[b, r, {phi2, phi1}]
 ]

poly = Polygon[{{0, 0}, {1, 2}, {2, 1}}];

Graphics[{EdgeForm[Thick], FaceForm[None], poly, 
  Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]}]

Mathematica graphics 

Manipulate[
 With[{poly = Polygon[{a, b, c}]},
  Graphics[
   {EdgeForm[Thick], FaceForm[None], poly, 
    Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]},
   PlotRange -> 2 {{-1, 1}, {-1, 1}}, Frame -> True
   ]
  ],
 {{a, {0, 0}}, Locator}, {{b, {1, 0}}, Locator}, {{c, {0, 1}}, Locator}
 ]

Mathematica graphics

14
répondu Szabolcs 2012-01-05 20:42:22

un excellent produit, soutenu par Wolfram est Geometrica . Ce n'est pas un add-on bon marché à 495$, mais il va produire des diagrammes comme le vôtre beaucoup plus facile que de les faire à l'état brut MMA Mathematica. Il s'agit essentiellement d'une très grande extension de L'approche Szabolcs dans les commentaires - une bibliothèque de fonctions pour dessiner des trucs.

9
répondu Tim Kemp 2012-01-05 19:53:36

J'aime beaucoup Mathematica. Mais il y a de meilleures options pour le dessin géométrique.

ici vous avez un sketch de cinq minutes fait avec expressions de géométrie (très basse résolution utilisée):

enter image description here

expressions de géométrie fait quelques beaux calculs de géométrie planaire et peut exporter les résultats à Mma en ligne.

8
répondu Dr. belisarius 2012-01-05 21:56:36

Oui, les outils graphiques intégrés de Mathematica sont un peu excentriques par endroits, et il y a quelques omissions ennuyeuses. Mais il ya une bonne gamme de graphiques de base, et, du côté positif, vous êtes seulement quelques touches loin des outils mathématiques dont vous avez besoin pour corriger certaines des lacunes de l'éditeur de graphiques. Besoin d'un arc? Juste calculer ci-dessous et copiez/collez la dans le. Je ne peux pas faire ça avec Adobe Illustrator! Il y a un large accès aux équations et aux Caractères grecs aussi. Il pourrait être utile quand il n'y a rien d'autre à portée de main.

Voici la première - ce n'est pas totalement inacceptable ... :)

mathematica built-in graphics

5
répondu cormullion 2012-01-05 22:40:46

présentations est un excellent et à faible coût (50$) graphiques (et beaucoup plus) paquet dans MMA, écrit par David Park. http://home.comcast.net/~djmpark/DrawGraphicsPage.html

, Il est mentionné comme ressource n.2 dans notre stackoverflow sac à outils Qu'est-ce qu'il y a dans votre sac à outils Mathematica?

5
répondu magma 2017-05-23 12:01:52