Barre de progression dans MS Access
J'ai une requête en cours D'exécution dans Microsoft Access 2010 et il faut plus de 30 min pour exécuter normalement. Je voudrais présenter à l'utilisateur final avec un certain statut de la requête. Une barre de progression serait bien mais pas obligatoire. L'accès semble être mal fileté et se bloque pendant l'exécution de la requête, annulant toutes les mises à jour que j'essaie. Alors que je préfère sortir VS et écrire ma propre application pour faire cela, je suis forcé d'utiliser L'accès.
Tout des idées?
EDIT
j'ai utilisé pour l'exécuter à partir d'un script batch qui peuplaient la base de données mais j'aimerais avoir tout autonome dans l'Accès. Pour être précis ,la "requête" est en fait un script VBA qui chante une série d'hôtes. Donc je ne suis pas préoccupé d'optimiser le temps en soi, mais simplement de laisser l'utilisateur de savoir qu'il n'a pas verrouillé.
7 réponses
je le fais souvent quelque chose comme ceci
Dim n As Long, db As DAO.Database, rs As DAO.Recordset
'Show the hour glass
DoCmd.Hourglass True
Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT ...")
rs.MoveLast 'Needed to get the accurate number of records
'Show the progress bar
SysCmd acSysCmdInitMeter, "working...", rs.RecordCount
rs.MoveFirst
Do Until rs.EOF
'Do the work here ...
'Update the progress bar
n = n + 1
SysCmd acSysCmdUpdateMeter, n
'Keep the application responding (optional)
DoEvents
rs.MoveNext
Loop
rs.Close: Set rs = Nothing
db.Close: Set db = Nothing
'Remove the progress bar
SysCmd acSysCmdRemoveMeter
'Show the normal cursor again
DoCmd.Hourglass False
Remarque: bien sûr, vous devez faire le travail par programme pour que cela fonctionne. Vous ne pouvez pas regarder une requête en cours d'exécution en code ou similaire en Accès. Vous pouvez aussi diviser le travail de votre requête lente en petits morceaux, afin d'avoir la chance de mettre à jour une barre de progression. Mais vous pouvez toujours afficher l'heure de verre; ceci indique à l'utilisateur que quelque chose se passe.
au cas où d'autres pourraient trouver cela utile, voici une classe que j'ai écrite dans ce but. Je l'utilise tout le temps dans mes projets de développement D'accès. Il suffit de le déposer dans votre projet dans un module de classe appelé clsLblProg, et l'utiliser comme ceci:
cela produit une jolie petite barre de progression:
Sur votre formulaire, vous n'avez besoin que de trois étiquettes. Mettez l'étiquette arrière à la taille désirée et faites les deux autres cachés. Le la classe fait le reste.
Et voici le code clsLblProg:
Option Compare Database
Option Explicit
' By Adam Waller
' Last Modified: 12/16/05
'Private Const sngOffset As Single = 1.5 ' For Excel
Private Const sngOffset As Single = 15 ' For Access
Private mdblMax As Double ' max value of progress bar
Private mdblVal As Double ' current value of progress bar
Private mdblFullWidth As Double ' width of front label at 100%
Private mdblIncSize As Double
Private mblnHideCap As Boolean ' display percent complete
Private mobjParent As Object ' parent of back label
Private mlblBack As Access.Label ' existing label for back
Private mlblFront As Access.Label ' label created for front
Private mlblCaption As Access.Label ' progress bar caption
Private mdteLastUpdate As Date ' Time last updated
Private mblnNotSmooth As Boolean ' Display smooth bar by doevents after every update.
' This class displays a progress bar created
' from 3 labels.
' to use, just add a label to your form,
' and use this back label to position the
' progress bar.
Public Sub Initialize(BackLabel As Access.Label, FrontLabel As Access.Label, CaptionLabel As Access.Label)
On Error GoTo 0 ' Debug Mode
Dim objParent As Object ' could be a form or tab control
Dim frm As Form
Set mobjParent = BackLabel.Parent
' set private variables
Set mlblBack = BackLabel
Set mlblFront = FrontLabel
Set mlblCaption = CaptionLabel
' set properties for back label
With mlblBack
.Visible = True
.SpecialEffect = 2 ' sunken. Seems to lose when not visible.
End With
' set properties for front label
With mlblFront
mdblFullWidth = mlblBack.Width - (sngOffset * 2)
.Left = mlblBack.Left + sngOffset
.Top = mlblBack.Top + sngOffset
.Width = 0
.Height = mlblBack.Height - (sngOffset * 2)
.Caption = ""
.BackColor = 8388608
.BackStyle = 1
.Visible = True
End With
' set properties for caption label
With mlblCaption
.Left = mlblBack.Left + 2
.Top = mlblBack.Top + 2
.Width = mlblBack.Width - 4
.Height = mlblBack.Height - 4
.TextAlign = 2 'fmTextAlignCenter
.BackStyle = 0 'fmBackStyleTransparent
.Caption = "0%"
.Visible = Not Me.HideCaption
.ForeColor = 16777215 ' white
End With
'Stop
Exit Sub
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Initialize", Erl
Resume Next ' Resume at next line.
End Select
End Sub
Private Sub Class_Terminate()
On Error GoTo 0 ' Debug Mode
On Error Resume Next
mlblFront.Visible = False
mlblCaption.Visible = False
On Error GoTo 0 ' Debug Mode
Exit Sub
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Class_Terminate", Erl
Resume Next ' Resume at next line.
End Select
End Sub
Public Property Get Max() As Double
On Error GoTo 0 ' Debug Mode
Max = mdblMax
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Max", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Let Max(ByVal dblMax As Double)
On Error GoTo 0 ' Debug Mode
mdblMax = dblMax
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Max", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Get Value() As Double
On Error GoTo 0 ' Debug Mode
Value = mdblVal
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Value", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Let Value(ByVal dblVal As Double)
On Error GoTo 0 ' Debug Mode
'update only if change is => 1%
If (CInt(dblVal * (100 / mdblMax))) > (CInt(mdblVal * (100 / mdblMax))) Then
mdblVal = dblVal
Update
Else
mdblVal = dblVal
End If
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Value", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Get IncrementSize() As Double
On Error GoTo 0 ' Debug Mode
IncrementSize = mdblIncSize
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "IncrementSize", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Let IncrementSize(ByVal dblSize As Double)
On Error GoTo 0 ' Debug Mode
mdblIncSize = dblSize
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "IncrementSize", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Get HideCaption() As Boolean
On Error GoTo 0 ' Debug Mode
HideCaption = mblnHideCap
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "HideCaption", Erl
Resume Next ' Resume at next line.
End Select
End Property
Public Property Let HideCaption(ByVal blnHide As Boolean)
On Error GoTo 0 ' Debug Mode
mblnHideCap = blnHide
Exit Property
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "HideCaption", Erl
Resume Next ' Resume at next line.
End Select
End Property
Private Sub Update()
On Error GoTo 0 ' Debug Mode
Dim intPercent As Integer
Dim dblWidth As Double
'On Error Resume Next
intPercent = mdblVal * (100 / mdblMax)
dblWidth = mdblVal * (mdblFullWidth / mdblMax)
mlblFront.Width = dblWidth
mlblCaption.Caption = intPercent & "%"
'mlblFront.Parent.Repaint ' may not be needed
' Use white or black, depending on progress
If Me.Value > (Me.Max / 2) Then
mlblCaption.ForeColor = 16777215 ' white
Else
mlblCaption.ForeColor = 0 ' black
End If
If mblnNotSmooth Then
If mdteLastUpdate <> Now Then
' update every second.
DoEvents
mdteLastUpdate = Now
End If
Else
DoEvents
End If
Exit Sub
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Update", Erl
Resume Next ' Resume at next line.
End Select
End Sub
Public Sub Increment()
On Error GoTo 0 ' Debug Mode
Dim dblVal As Double
dblVal = Me.Value
If dblVal < Me.Max Then
Me.Value = dblVal + 1
'Call Update
End If
Exit Sub
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Increment", Erl
Resume Next ' Resume at next line.
End Select
End Sub
Public Sub Clear()
On Error GoTo 0 ' Debug Mode
Call Class_Terminate
Exit Sub
ErrHandler:
Select Case Err.Number
Case Else
LogErr Err, "clsLblProg", "Clear", Erl
Resume Next ' Resume at next line.
End Select
End Sub
Private Function ParentForm(ctlControl As Control) As String
' returns the name of the parent form
Dim objParent As Object
Set objParent = ctlControl
Do While Not TypeOf objParent Is Form
Set objParent = objParent.Parent
Loop
' Now we should have the parent form
ParentForm = objParent.Name
End Function
Public Property Get Smooth() As Boolean
' Display the progress bar smoothly.
' True by default, this property allows the call
' to doevents after every increment.
' If False, it will only update once per second.
' (This may increase speed for fast progresses.)
'
' negative to set default to true
Smooth = mblnNotSmooth
End Property
Public Property Let Smooth(ByVal IsSmooth As Boolean)
mblnNotSmooth = Not IsSmooth
End Property
Private Sub LogErr(objErr, strMod, strProc, intLine)
' For future use.
End Sub
en raison de problèmes avec le contrôle disponible, j'ai créé une barre de progression maison en utilisant 2 rectangles. Une frontière solide barre de redimensionnement que les choses progressent. Les progrès rectangle en face de la frontière. Pour utiliser
If pbar Is Nothing Then
Set pbar = New pBar_sub
pbar.init Me.Progressbar_border, Me.ProgressBar_Bar
End If
pbar.value = 0
pbar.show
pbar.max = 145 ' number of interations
...
...
Do While Not recset.EOF
count = count + 1
pbar.value = count
' get next
recset.MoveNext
Loop
on peut associer une ligne de statut avec la barre de progression qui annonce quel élément est traité. Comme: 123. District quelque part, l'agent de vente Qui
======== la Barre de Progression de remplacer pBar_sub ==============
Option Compare Database
Option Explicit
Dim position As Long
Dim maximum As Long
Dim increment As Single
Dim border As Object
Dim bar As Object
Sub init(rect As Object, b As Object)
Set border = rect
Set bar = b
bar.width = 0
hide
End Sub
Sub hide()
bar.visible = False
border.visible = False
End Sub
Sub show()
bar.visible = True
border.visible = True
End Sub
Property Get Max() As Integer
Max = maximum
End Property
Property Let Max(val As Integer)
maximum = val
increment = border.width / val
End Property
Property Get value() As Integer
value = position
End Property
Property Let value(val As Integer)
position = val
bar.width = increment * value
End Property
Utilisez la commande DoEvents après mise à jour de la barre de progression (acSysCmdUpdateMeter).
dans le cas d'un grand nombre d'enregistrements n'exécutez DoEvents que x fois car cela ralentit un peu votre application.
Ce n'est pas une manière professionnelle, mais peut être appliquée que si vous l'aimez. Si vous utilisez un formulaire Vous pouvez avoir une petite zone de texte dans un endroit pratique par défaut avec la couleur Verte.
supposons que le nom de la zone de texte soit TxtProcessing,
Propriétés peuvent être comme ci-dessous.
Name : TxtProcessing
Visible : Yes
Back color : Green
Locked: Yes
Enter Key Behavior : Default
1) dans votre script VB vous pouvez mettre Me.TxtProcessing.BackColor = vbRed qui sera en rouge et qui signifie la tâche en cours.
2) Vous pouvez écrire tout votre ensemble de scripts
3) enfin, vous pouvez mettre Me.TxtProcessing.BackColor = vbGreen
Me.TxtProcessing.BackColor = vbRed
Me.TxtProcessing.SetFocus
Me.Refresh
Your Code here.....
Me.TxtProcessing.BackColor = vbGreen
Me.TxtProcessing.SetFocus
:-) Drôle, mais le but est atteint.
je viens d'ajouter ma part à la collection ci-dessus pour les futurs lecteurs.
si vous êtes après moins de code et peut-être L'interface utilisateur cool. Découvrez mon GitHub pour Progressbar pour VBA
personnalisable:
la Dll est pensé pour MS-Access, mais doit fonctionner dans toutes les plate-formes VBA avec des changements mineurs. Tous les codes se trouvent dans la base de données de l'échantillon.
ce le projet est en cours d'élaboration et toutes les erreurs ne sont pas couvertes. Alors attendez-vous des!
vous devriez être inquiet au sujet de tiers dlls et si vous êtes, s'il vous plaît n'hésitez pas à utiliser tout antivirus en ligne de confiance avant de mettre en œuvre la dll.
d'abord faire glisser le contrôle de barre progressive dans la forme D'accès MS, puis changer le nom de barre progressive comme aa.
alors allez à form property, sur timer :write EN code
me.aa.value=me.aa.value+20
intervalle de temps 300 selon votre choix. Exécutez le formulaire vous verrez la barre progressive