Comment transférer les données des colonnes en lignes (avec awk)?
j'ai un fichier comme ceci:
n A B C D
1 01 02 01 01
2 02 02 01 01
et je veux transférer les colonnes en lignes, de sorte que la sortie devrait ressembler à ceci:
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01
j'ai écrit cette commande:
awk '{ for (i=1;i<=NF;i++ ) printf $i " " }' file.txt > out-file.txt
le problème est que cette commande met tout sur une ligne! la sortie ressemble à ceci:
n 1 2 A 01 02 B 02 02 C 01 01 D 01 01
5 réponses
Cela peut fonctionner:
awk '{
for (f = 1; f <= NF; f++) { a[NR, f] = $f }
}
NF > nf { nf = NF }
END {
for (f = 1; f <= nf; f++) {
for (r = 1; r <= NR; r++) {
printf a[r, f] (r==NR ? RS : FS)
}
}
}' YOURINPUT
Voir dans l'action @ Ideone.
enregistrez ce script comme transpose.awk et chmod u+x transpose.awk. C'est une modification Tim Sherwood esttranspose.
#!/usr/bin/gawk -f
BEGIN {
max_x =0;
max_y =0;
}
{
max_y++;
for( i=1; i<=NF; i++ )
{
if (i>max_x) max_x=i;
A[i,max_y] = $i;
}
}
END {
for ( x=1; x<=max_x; x++ )
{
for ( y=1; y<=max_y; y++ )
{
if ( (x,y) in A ) printf "%s",A[x,y];
if ( y!=max_y ) printf " ";
}
printf "\n";
}
}
Exemple:
$ ./transpose.awk example
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01
Il serait plus facile à utiliser rs:
$ cat /tmp/a
n A B C D
1 01 02 01 01
2 02 02 01 01
$ rs -c' ' -C' ' -T</tmp/a
n 1 2
A 01 02
B 02 02
C 01 01
D 01 01
-c les changements de la colonne d'entrée du séparateur, -C change le séparateur de colonne de sortie, et -T transpose les lignes et les colonnes.
Bien, sans awk nous pouvons le faire avec cat:
for x in `cat filename`
do
echo $x
done
avec ce script le résultat apparaîtra dans cols.
Voici une solution différente, qui implique seulement un pour boucle à la fin:
{ for (i=1; i<=NF; i++) col[i] = col[i] " " $i }
END {
for (i=1; i<=NF; i++) {
sub(/^ /, "", col[i]);
print col[i]
}
}
Discussion
- Cette solution utilise un tableau en une seule dimension col, qui stocke la valeur pour la colonne entière. col [1] c'est la première colonne.
- pour chaque ligne, nous ajoutons la colonne au col [i]. Parce que nous ajoutons aveuglément, le col [i] valeur contient un espace.
- À la fin, le sous() la fonction supprime l'espace blanc avant d'Imprimer la colonne (maintenant une rangée)