Comment sauvegarder et restaurer un formulaire?

la solution de PRUZ est une solution prête à l'emploi; JVCL est open-source, et l'utilisation de JvFormStorage est simple. Mais vous pouvez également utiliser Delphi propre streaming mécanisme sans l'aide des composants tiers. Voici un exemple:

procedure SaveComponentToFile(Component: TComponent; const FileName: TFileName);
var
  FileStream : TFileStream;
  MemStream : TMemoryStream;
begin
  MemStream := nil;

  if not Assigned(Component) then
    raise Exception.Create('Component is not assigned');

  FileStream := TFileStream.Create(FileName,fmCreate);
  try
    MemStream := TMemoryStream.Create;
    MemStream.WriteComponent(Component);
    MemStream.Position := 0;
    ObjectBinaryToText(MemStream, FileStream);
  finally
    MemStream.Free;
    FileStream.Free;
  end;
end;

SaveComponentToFile prend une instance component, plus un nom de fichier, et envoie le component dans le fichier, dans un texte lisible par l'humain.

pour charger le composant à partir du fichier, vous pouvez utiliser un code comme ceci:

procedure LoadComponentFromFile(Component: TComponent; const FileName: TFileName);
var
  FileStream : TFileStream;
  MemStream : TMemoryStream;
  i: Integer;
begin
  MemStream := nil;

  if not Assigned(Component) then
    raise Exception.Create('Component is not assigned');

  if FileExists(FileName) then
  begin
    FileStream := TFileStream.Create(FileName,fmOpenRead);
    try
      for i := Component.ComponentCount - 1 downto 0 do
      begin
        if Component.Components[i] is TControl then
          TControl(Component.Components[i]).Parent := nil;
        Component.Components[i].Free;
      end;

      MemStream := TMemoryStream.Create;
      ObjectTextToBinary(FileStream, MemStream);
      MemStream.Position := 0;
      MemStream.ReadComponent(Component);
      Application.InsertComponent(Component);
    finally
      MemStream.Free;
      FileStream.Free;
    end;
  end;
end;

LoadComponentFromFile prend une instance component, et un nom de fichier, puis charge le contenu du fichier dans l'instance component. Pour éviter de nommer un conflit, nous sommes libres de tous les composants existants appartenant à l'instance, avant d'y charger des données de fichier.

vous pouvez maintenant utiliser le code ci-dessus pour sauvegarder un formulaire dans un fichier:

  SaveComponentToFile(FSecondForm,ExtractFilePath(Application.ExeName)+ 'formdata.txt');

FSecondForm est une instance form, et elle sera sauvegardée dans formdata.txt " fichier à l'intérieur du même dossier que L'EXE fichier.

et de charger un second formulaire à partir de " formdata.txt" un fichier, nous écrire ceci:

  if not Assigned(FSecondForm) then
    FSecondForm := TfrmSecond.Create(Application);
  LoadComponentFromFile(FSecondForm,ExtractFilePath(Application.ExeName)+ 'formdata.txt');
  FSecondForm.Show;

LoadComponentFromFile a besoin que l'instance soit créée en premier, donc nous vérifions si FSecondForm est assignée, sinon, nous en créons une instance (c'est une instance de la classe TfrmSecond), puis nous y chargeons les données du fichier. Et finalement, nous montrons la forme chargée.