Comment ouvrir une URL avec le navigateur par défaut avec des applications multi-plateformes FireMonkey?

Généralement, j'utilise: ShellExecute(0, 'OPEN', PChar(edtURL.Text), '', '', SW_SHOWNORMAL);

Comment puis-je avoir le même comportement (ouvrir un lien dans le navigateur par défaut), sur toutes les plates-formes (Windows et OSX)?

27
demandé sur Whiler 2011-09-16 14:20:08

8 réponses

Dans le forum de discussion FireMonkey, j'ai trouvé ce code pour une question sur NSWorkspace.URLForApplicationToOpenURL:

uses
  Posix.Stdlib;
....
  _system(PAnsiChar('open ' + ACommand));

(non testé par moi)


Update : Posix n'est pas disponible sous Windows, il n'est donc pas possible d'écrire une solution qui utilise les mêmes appels OS sur toutes les plates-formes. Je suggère de déplacer un tel code dans une unité centrale 'XPlatform' qui a un certain ifdef POSIX etc.

12
répondu mjn 2013-03-06 06:22:52

Concernant la réponse de mjn, j'ai écrit l'unité. Je l'ai testé avec succès sur Windows mais je n'ai pas D'OSX pour le tester sur cette plate-forme. Si quelqu'un peut confirmer que cela fonctionne, j'apprécierais.

unit fOpen;

interface

uses
{$IFDEF MSWINDOWS}
  Winapi.ShellAPI, Winapi.Windows;
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  Posix.Stdlib;
{$ENDIF POSIX}

type
  TMisc = class
    class procedure Open(sCommand: string);
  end;

implementation

class procedure TMisc.Open(sCommand: string);
begin
{$IFDEF MSWINDOWS}
  ShellExecute(0, 'OPEN', PChar(sCommand), '', '', SW_SHOWNORMAL);
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
  _system(PAnsiChar('open ' + AnsiString(sCommand)));
{$ENDIF POSIX}
end;

end.

Et je l'appelle comme ceci:

TMisc.Open('https://stackoverflow.com/questions/7443264/how-to-open-an-url-with-the-default-browser-with-firemonkey-cross-platform-applic');
17
répondu Whiler 2017-05-23 12:32:29

Code XE2 c++ testé avec succès (Windows 7 64 et OSX Lion), améliorations mineures. Merci encore, la douleur est terminée:)

#include <fmx.h>
// ---------------------------------------------------------------------------
#ifdef _WIN32
#include <shellapi.h>
#endif// Windows
#ifdef TARGET_OS_MAC
#include <Posix.Stdlib.hpp>
#endif // Mac

void OpenCommand(String _sCommand) {
    #ifdef _Windows
    String open = "open";
    ShellExecute(0, open.w_str(), _sCommand.c_str(), NULL, NULL, SW_SHOWNORMAL);
    #endif // Windows

    #ifdef TARGET_OS_MAC
    system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif // Mac
}
3
répondu Tuomas Kayhko 2016-12-23 23:10:04

Pour toutes les plates-formes (Windows, macOs, iOS et Android), vous pouvez utiliser l'unité que j'ai écrite pour mon blog

unit u_urlOpen;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes,
  System.Variants,
{$IF Defined(IOS)}
  macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS;
{$ELSEIF Defined(ANDROID)}
Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Net,
   Androidapi.JNI.App,
  Androidapi.helpers;
{$ELSEIF Defined(MACOS)}
Posix.Stdlib;
{$ELSEIF Defined(MSWINDOWS)}
Winapi.ShellAPI, Winapi.Windows;
{$ENDIF}

type
  tUrlOpen = class
    class procedure Open(URL: string);
  end;

implementation

class procedure tUrlOpen.Open(URL: string);
{$IF Defined(ANDROID)}
var
  Intent: JIntent;
{$ENDIF}
begin
{$IF Defined(ANDROID)}
  Intent := TJIntent.Create;
  Intent.setAction(TJIntent.JavaClass.ACTION_VIEW);
  Intent.setData(StrToJURI(URL));
  tandroidhelper.Activity.startActivity(Intent);
  // SharedActivity.startActivity(Intent);
{$ELSEIF Defined(MSWINDOWS)}
  ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL);
{$ELSEIF Defined(IOS)}
  SharedApplication.OpenURL(StrToNSUrl(URL));
{$ELSEIF Defined(MACOS)}
  _system(PAnsiChar('open ' + AnsiString(URL)));
{$ENDIF}
end;

end.
3
répondu Patrick PREMARTIN 2017-08-23 09:11:25

Comme @NicoBlu l'a mentionné, la solution acceptée semble tronquer l'URL après la première occurrence de'&'. Voici ce qui fonctionne pour moi sans troncature:

uses Macapi.AppKit, Macapi.Foundation, Macapi.Helpers;

// ...

procedure OpenLinkInDefaultBrowser(const Link: string);
  var URL : NSURL;
      Workspace : NSWorkspace;
begin
  URL := TNSURL.Wrap(TNSURL.OCClass.URLWithString(StrToNSStr(Link)));
  Workspace := TNSWorkspace.Wrap(TNSWorkspace.OCClass.sharedWorkspace);
  Workspace.openURL(URL);
end;
1
répondu DNR 2016-02-07 09:41:59

Et maintenant une version C++ (Code OSx non testé, pas sûr non plus du _posix #def):

#ifdef _Windows
#include <Winapi.Windows.hpp>
#endif // _Windows
#ifdef _POSIX
#include <Posix.Stdlib.h>
#endif // _POSIX

void OpenCommand(String _sCommand)
{
    #ifdef _Windows
    ShellExecute(0, _T("open"), _sCommand.c_str(), _T(""), _T(""), SW_SHOWNORMAL);
    #endif // _Windows
    #ifdef _POSIX
    _system(AnsiString("open " + AnsiString(_sCommand)).c_str());
    #endif // _POSIX
}
1
répondu Rhys Drummond 2016-12-23 23:11:39
_system(PAnsiChar('open ' + AnsiString(sCommand)));

Ne fonctionne pas si la chaîne D'URL (sCommand) inclut le caractère Esperluette (&), nécessaire pour spécifier de nombreux arguments dans querystring.

URL envoyée à def. le navigateur dans OSX (Safari) est tronqué à la première occurrence de &.

0
répondu NicoBlu 2015-07-24 07:40:46
LEncodedString : String;

begin
    LEncodedString := TIdURI.URLEncode('http://www.malcolmgroves.com');
    sharedApplication.openURL(StringToNSURL(LEncodedString));
end;
0
répondu Maxime Bonin 2016-12-28 15:17:11