Comment gérer un événement de clic dans la colonne bouton dans Datagridview?

vous avez ajouté un bouton à votre DataGridView et vous voulez lancer un code quand il est cliqué.

Easy peasy - il suffit de suivre ces étapes:

Don't:

tout D'abord, voici ce que pas à faire:

je voudrais éviter les suggestions dans certaines des autres réponses ici et même fourni par la documentation à MSDN pour le codage dur l'index de colonne ou nom de la colonne afin de déterminer si un bouton a été cliqué. L'événement de clic Enregistre pour la grille entière, donc d'une certaine façon vous devez déterminer qu'un bouton a été cliqué, mais vous ne devriez pas le faire en supposant que votre bouton vit dans un nom de colonne particulier ou index... il y a un moyen plus facile...

aussi, faites attention à l'événement que vous voulez gérer. Encore une fois, la documentation et de nombreux exemples se trompent. La plupart des exemples traitent du CellClick événement qui va tirer:

lorsqu'une partie d'une cellule est cliquée.

...mais va également le feu chaque fois que le ligne en-tête est cliqué. Il faut donc ajouter du code supplémentaire simplement pour déterminer si la valeur e.RowIndex est inférieure à 0

au lieu de manipuler le CellContentClick qui se produit seulement:

lorsque le le contenu d'une cellule est cliqué

pour quelque raison que ce soit, l'en-tête de la colonne est également considéré comme "contenu" dans une cellule, donc nous devrons toujours vérifier cela ci-dessous.

Dos:

alors voici ce que vous devez faire:

D'abord, moulé l'expéditeur à taper DataGridView pour exposer ses propriétés internes au moment de la conception. Vous pouvez modifier la tapez sur le paramètre, mais cela peut parfois rendre difficile l'ajout ou la suppression de gestionnaires.

ensuite, pour voir si un bouton a été cliqué, il suffit de vérifier pour s'assurer que la colonne soulevant l'événement est de type DataGridViewButtonColumn . Parce que nous avons déjà moulé l'expéditeur pour taper DataGridView , nous pouvons obtenir la collection Columns et sélectionner la colonne courante en utilisant e.ColumnIndex . Vérifiez ensuite si cet objet est du type DataGridViewButtonColumn .

bien sûr, si vous avez besoin de distinguer entre plusieurs boutons par grille, vous pouvez sélectionner en fonction du nom de la colonne ou de l'index, mais ce ne devrait pas être votre première vérification. Assurez-vous toujours qu'un bouton a été cliqué en premier et ensuite manipuler n'importe quoi d'autre de manière appropriée. Dans la plupart des cas où vous n'avez qu'un seul bouton par grille, vous pouvez sauter directement aux courses.

Mettre tous ensemble:

c# :

private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
    var senderGrid = (DataGridView)sender;

    if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
        e.RowIndex >= 0)
    {
        //TODO - Button Clicked - Execute Code Here
    }
}

VB :

Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
                                           Handles DataGridView1.CellContentClick
    Dim senderGrid = DirectCast(sender, DataGridView)

    If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
       e.RowIndex >= 0 Then
        'TODO - Button Clicked - Execute Code Here
    End If

End Sub

---

Mise À Jour 1 - Événement Personnalisé

Si vous voulez avoir un peu de plaisir, vous pouvez ajouter votre propre événement est déclenché lorsqu'un bouton est cliqué sur la grille de données. Vous ne pouvez pas l'ajouter à la base de données elle-même, sans vous embrouiller avec l'héritage, etc. mais vous pouvez ajouter un événement personnalisé à votre formulaire et le feu au moment opportun. C'est un peu plus le code, mais l'avantage est que vous avons séparé ce que vous voulez faire quand un bouton est cliqué avec la façon de déterminer si un bouton a été cliqué.

il suffit de déclarer un événement, de le soulever le cas échéant, et de le gérer. Il ressemblera à ceci:

Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)

Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
    Dim senderGrid = DirectCast(sender, DataGridView)
    If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
        RaiseEvent DataGridView1ButtonClick(senderGrid, e)
    End If
End Sub

Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
    'TODO - Button Clicked - Execute Code Here
End Sub

---

Mise À Jour 2 - Extension De La Grille

ce qui serait génial c'est que nous travaillions avec une grille qui vient de faire ces choses pour nous. Nous pourrions répondre à la question initiale facilement: you've added a button to your DataGridView and you want to run some code when it's clicked . Voici une approche qui prolonge le DataGridView . Il ne vaut peut-être pas la peine d'avoir à livrer un contrôle personnalisé avec chaque bibliothèque, mais au moins il réutilise au maximum le code utilisé pour déterminer si un bouton a été cliqué.

il suffit d'ajouter ceci à votre assemblage:

Public Class DataGridViewExt : Inherits DataGridView

    Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)

    Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
        If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
            RaiseEvent CellButtonClick(Me, e)
        End If
    End Sub

End Class

C'est ça. Ne jamais toucher à nouveau. Assurez-vous que votre DataGrid est de type DataGridViewExt qui devrait fonctionner exactement le même en tant que DataGridView. Sauf qu'il va également soulever un événement supplémentaire que vous pouvez gérer comme ceci:

Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
                                      Handles DataGridView1.CellButtonClick
    'TODO - Button Clicked - Execute Code Here
End Sub