Obtenez la liste des arguments passés dans le script batch de Windows (.chauve)

%* semble contenir tous les arguments passés au script.

%1 ... %n et %* détient les arguments, mais il peut être difficile d'y accéder, parce que le contenu sera interprété.

Par conséquent, il est impossible de gérer quelque chose comme cela avec des déclarations normales

myBatch.bat "&"^&

chaque ligne échoue, comme cmd.exe essayez d'exécuter l'un de l'esperluette (le contenu de %1 est "&"& )

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

mais il existe une solution avec un dossier temporaire

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

le truc est d'activer echo on et d'étendre le %1 après un énoncé rem (fonctionne aussi avec %2 .. %*).

Mais pour pouvoir rediriger la sortie de echo on , vous avez besoin des deux for-LOOPS.

les caractères supplémentaires * # sont utilisés pour être sûr contre des contenus comme /? (montrerait L'aide pour REM).

Ou un accent circonflexe ^ la fin de ligne peut travailler comme multiligne caractère.

Le POUR /F doit être un travail avec expansion retardée off, d'autre contenu avec "!"serait détruit.

Après avoir enlevé les caractères supplémentaires dans param1 et vous l'avez.

et d'utiliser param1 d'une manière sûre, activer l'expansion retardée.

Edit: une remarque à %0

%0 contient la commande utilisée pour appeler le lot, en conservant également le cas comme dans FoO.BaT

Mais après un appel à une fonction %0 et aussi dans %~0 contient le nom de la fonction (ou mieux la chaîne qui a été utilisée pour appeler la fonction).

Mais avec %~f0 vous pouvez toujours vous rappeler le nom du fichier.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

sortie

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

j'ai trouvé que la prochaine fois, quand vous avez besoin de rechercher ces informations. Au lieu d'ouvrir un navigateur et google, vous tapez juste call /? dans votre cmd et vous l'obtiendrez:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

La façon de récupérer tous les arguments d'un script est ici:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

voici un moyen assez simple pour obtenir les args et les mettre comme env vars. Dans cet exemple, je vais simplement les appeler clés et valeurs.

Enregistrer l'exemple de code suivant en tant que "args.chauve." Appelez ensuite le fichier de commandes vous avez sauvé d'une ligne de commande. exemple: arg.chauve-souris --x 90 --a 120

j'ai fourni quelques commandes echo pour vous guider dans le processus. Mais l' le résultat final est que --x a une valeur de 90 et --y aura une valeur de 120(c'est si vous exécutez l'exemple, comme spécifié ci-dessus ;-) ).

vous pouvez alors utiliser l'instruction conditionnelle 'if defined' pour déterminer si vous devez ou non exécuter votre bloc de code. Donc disons exécuter: "arg.chauve-souris --x hello-world" Je pourrais alors utiliser la déclaration "IF DEFINED --x echo %--x%" et les résultats seraient "hello-world". Il devrait faire plus de sens si vous lancez le lot.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

le code suivant simule un tableau (' params ') - prend les paramètres reçus par le script et les stocke dans les variables params_1 .. params_n , où n = params_0 =le nombre d'éléments du tableau:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

@echo off
:start

:: Insert your code here
echo.%%1 is now:%~1
:: End insert your code here

if "%~2" NEQ "" (
    shift
    goto :start
)

beaucoup des informations ci-dessus m'ont amené à poursuivre des recherches et finalement ma réponse, alors j'ai voulu contribuer ce que j'ai fini par faire dans l'espoir qu'il aide quelqu'un d'autre:

• je voulais aussi passer un nombre varié de variables à un fichier par lots afin qu'elles puissent être traitées dans le fichier.

• j'étais d'accord pour les passer au fichier batch en utilisant les citations

• je voudrais qu'ils soient traités comme ci - dessous-mais en utilisant une boucle au lieu d'écrire manuellement:

alors j'ai voulu exécuter ceci:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

et via la magie des boucles font ceci dans le fichier batch:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

le problème que j'ai eu est que toutes mes tentatives d'utiliser un pour boucle ne fonctionnaient pas. L'exemple suivant:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

serait juste do:

set "_appPath=C:\Services\Logs\PCAP"

et non:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

même après le réglage de

SETLOCAL EnableDelayedExpansion

était que la boucle for lisait toute la ligne et assignait mon second paramètre à %%B pendant la première itération de la boucle. Puisque %* représente tous les arguments, il n'y a qu'une seule ligne à traiter - par conséquent, une seule passe de la boucle for se produit. Il s'avère que c'est fait exprès, et ma logique était fausse.

So J'ai arrêté d'essayer d'utiliser une boucle for et j'ai simplifié ce que j'essayais de faire en utilisant if, shift, et une instruction goto. Arrêté un peu un hack mais c'est plus adapté à mes besoins. Je peux passer en boucle tous les arguments et ensuite utiliser une instruction if pour sortir de la boucle une fois que je les ai tous traités.

La réussite de déclaration pour ce que j'étais en train d'essayer d'accomplir:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

mise à jour - j'ai dû modifier à la place, je exposais tous les variables d'environnement lorsqu'on essaie de faire référence à %1 et qu'on utilise shift de cette manière:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

si vous avez des paramètres entre guillemets qui contiennent des espaces, %* ne fonctionnera pas correctement. La meilleure solution que j'ai trouvée est d'avoir une boucle qui unit tous les arguments: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

version Windows (needs socat though)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

mise en place:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd

vous pouvez utiliser %1, %2 etc pour accéder aux arguments en ligne de commande. Je ne pense pas qu'il y ait une variable qui tienne toute la liste. Vous pourriez être en mesure d'écrire une boucle simple qui détermine combien d'arguments ont été passés.

EDIT: Apparemment il y en a :)

Pour quelqu'un qui a besoin de barre oblique de fin basepath

set source=%~dp0
::Remove the trailing backslash from source
IF %source:~-1%==\ SET source=%source:~0,-1%
echo %source%