Activer les connexions à distance tcpip vers sql server express base de données déjà installée avec du code ou un script(requête)

j'ai testé ci-dessous le code avec SQL Server 2008 R2 Express et je crois que nous devrions avoir une solution pour les 6 étapes que vous avez décrites. Prenons-les un à un:

1-Activer TCP / IP

nous pouvons activer le protocole TCP/IP avec WMI :

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProtocols = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocol " _
    & "where InstanceName = 'SQLEXPRESS' and ProtocolName = 'Tcp'")

if tcpProtocols.Count = 1 then
    ' set tcpProtocol = tcpProtocols(0)
    ' I wish this worked, but unfortunately 
    ' there's no int-indexed Item property in this type

    ' Doing this instead
    for each tcpProtocol in tcpProtocols
        dim setEnableResult
            setEnableResult = tcpProtocol.SetEnable()
            if setEnableResult <> 0 then 
                Wscript.Echo "Failed!"
            end if
    next
end if

2-Ouvrez les ports de droite dans le pare-feu

je crois que votre solution va fonctionner, assurez-vous juste vous spécifiez le bon port. Je suggère que nous choisissions un port différent de 1433 et en faire un port SQL Server Express statique sera à l'écoute. Je vais être en utilisant 3456 dans ce post, mais s'il vous plaît choisir un autre numéro dans la mise en œuvre réelle (je pense que nous allons voir beaucoup d'applications à l'aide de 3456 bientôt :-)

3-Modifier les propriétés TCP/IP activer une adresse IP

Nous pouvons utiliser WMI de nouveau. Puisque nous utilisons le port 3456 statique, nous avons juste besoin de mettre à jour deux propriétés dans IPAll section: Désactiver les ports dynamiques et régler le port d'écoute à 3456 :

set wmiComputer = GetObject( _
    "winmgmts:" _
    & "\.\root\Microsoft\SqlServer\ComputerManagement10")
set tcpProperties = wmiComputer.ExecQuery( _
    "select * from ServerNetworkProtocolProperty " _
    & "where InstanceName='SQLEXPRESS' and " _
    & "ProtocolName='Tcp' and IPAddressName='IPAll'")

for each tcpProperty in tcpProperties
    dim setValueResult, requestedValue

    if tcpProperty.PropertyName = "TcpPort" then
        requestedValue = "3456"
    elseif tcpProperty.PropertyName ="TcpDynamicPorts" then
        requestedValue = ""
    end if

    setValueResult = tcpProperty.SetStringValue(requestedValue)
    if setValueResult = 0 then 
        Wscript.Echo "" & tcpProperty.PropertyName & " set."
    else
        Wscript.Echo "" & tcpProperty.PropertyName & " failed!"
    end if
next

Notez que je n'ai pas à activer l'une des adresses individuelles pour le faire fonctionner, mais si c'est nécessaire dans votre cas, vous devriez être en mesure d'étendre ce script facilement à le faire.

Juste un rappel que lorsque l'on travaille avec WMI, WBEMTest.exe est votre meilleur ami!

4-Activer l'authentification en mode mixte dans le serveur sql

j'aimerais que nous puissions utiliser WMI à nouveau, mais malheureusement ce cadre n'est pas exposé par WMI. Il y a deux autres options:

1. utiliser LoginMode bien de la catégorie Microsoft.SqlServer.Management.Smo.Server , tel que décrit ici .

2. utiliser la valeur LoginMode dans le registre SQL Server, comme décrit dans ceci post . Notez que par défaut L'instance SQL Server Express est appelée SQLEXPRESS , donc pour mon instance SQL Server 2008 R2 Express la clé de registre de droite était HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Microsoft SQL Server\MSSQL10_50.SQLEXPRESS\MSSQLServer .

5 - Changer d'utilisateur (sa) mot de passe par défaut

tu t'en occupes.

6-Enfin (connexion à l'instance)

puisque nous utilisons un port statique assigné à notre SQL Server Express par exemple, il n'est plus nécessaire d'utiliser le nom d'instance dans l'adresse du serveur.

SQLCMD -U sa -P newPassword -S 192.168.0.120,3456

s'il vous plaît faites-moi savoir si cela fonctionne pour vous (doigts croisés!).