ANTLR: y a-t-il un exemple simple?

vous créez d'abord une grammaire. Ci-dessous une petite grammaire que vous pouvez utiliser pour évaluer les expressions qui sont construites en utilisant les 4 opérateurs mathématiques de base:+, -, * et /. Vous pouvez également grouper des expressions en utilisant la parenthèse.

notez que cette grammaire n'est qu'une grammaire de base: elle ne gère pas les opérateurs unaires (le moins en: -1+9) ou décimales comme .99 (sans numéro), pour ne citer que deux lacunes. C'est juste un exemple, vous pouvez travailler sur vous-même.

Voici le contenu du fichier de grammaire Exp.g :

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

après avoir créé la grammaire, vous voudrez générer un analyseur et lexer à partir de celui-ci. Téléchargez le ANTLR jar et stockez-le dans le même répertoire que votre fichier de grammaire.

exécutez la commande suivante sur votre invite shell / commande:

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

il ne doit pas produire de message d'erreur, et les fichiers Expresser.java , ExpParser.java et Exp.les tokens devraient maintenant être générés.

pour voir si tout fonctionne correctement, créez cette classe d'essai:

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        parser.eval();
    }
}

et le compiler:

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

puis lancez-le:

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

Si tout va bien, rien n'est imprimé sur la console. Cela signifie que l'analyseur n'a trouvé aucune erreur. Lorsque vous changez "12*(5-6)" en "12*(5-6" et que vous le recompilez et l'exécutez, il faut imprimer ce qui suit:

line 0:-1 mismatched input '<EOF>' expecting ')'

Ok, maintenant nous voulons ajouter un peu de code Java à la grammaire pour que l'analyseur fasse quelque chose d'utile. L'ajout de code peut être fait par placer { et } dans votre grammaire avec un code Java simple à l'intérieur.

mais d'abord: toutes les règles de l'analyseur dans le fichier grammatical doivent retourner une valeur primitive double. Vous pouvez le faire en ajoutant returns [double value] après chaque règle:

grammar Exp;

eval returns [double value]
    :    additionExp
    ;

additionExp returns [double value]
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

// ...

ce qui nécessite peu d'explications: chaque règle est censée rapporter une double valeur. Maintenant, pour "interagir" avec la valeur de retour double value (qui N'est pas à l'intérieur d'un bloc de code Java simple {...} ) de l'intérieur d'un bloc de code, vous devrez ajouter un signe dollar en face de value :

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

voici la grammaire mais maintenant avec le code Java ajouté:

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

et puisque notre règle eval retourne maintenant un double, changez votre ANTLRDemo.java dans le présent:

import org.antlr.runtime.*;

public class ANTLRDemo {
    public static void main(String[] args) throws Exception {
        ANTLRStringStream in = new ANTLRStringStream("12*(5-6)");
        ExpLexer lexer = new ExpLexer(in);
        CommonTokenStream tokens = new CommonTokenStream(lexer);
        ExpParser parser = new ExpParser(tokens);
        System.out.println(parser.eval()); // print the value
    }
}

encore une fois (re) générer une lexer et un analyseur à partir de votre grammaire( 1), compiler toutes les classes (2) et exécuter ANTLRDemo (3):

// *nix/MacOS
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .:antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .:antlr-3.2.jar ANTLRDemo            // 3

// Windows
java -cp antlr-3.2.jar org.antlr.Tool Exp.g   // 1
javac -cp .;antlr-3.2.jar ANTLRDemo.java      // 2
java -cp .;antlr-3.2.jar ANTLRDemo            // 3

et vous verrez maintenant le résultat de l'expression 12*(5-6) imprimé sur votre console!

Encore une fois: c'est une très brève explication. Je vous encourage à parcourir le ANTLR wiki et lire quelques tutoriels et/ou jouer un peu avec ce que je viens de poster.

bonne chance!

EDIT:

Ce post , montre comment étendre l'exemple ci-dessus pour qu'un Map<String, Double> puisse être fourni qui contient des variables dans l'expression fournie.

et ce Q&A montre comment créer un analyseur d'expression simple, et un évaluateur en utilisant ANTLR4 .

pour que ce code fonctionne avec une version actuelle D'Antlr (juin 2014) j'ai dû faire quelques changements. ANTLRStringStream devait devenir ANTLRInputStream , la valeur retournée nécessaire de passer de parser.eval() à parser.eval().value , et j'ai dû supprimer la clause WS à la fin, parce que les valeurs d'attribut telles que $channel ne sont plus autorisées à apparaître dans les actions de lexer.